On Error Resume Next
Dim colResults, objResult, strWMIQuery
Dim objLocator, objWMI
Dim objArgs
Dim objNetwork

Set objNetwork=CreateObject("WScript.Network")

Set objArgs=WScript.Arguments
If objArgs.Count < 1 Then
    WScript.Echo "You failed to specify a computer name!"
    WScript.Echo "Example: cscript GetInfo.vbs computername " &_
    "[domain\admin] [password]"
    WScript.Quit
    
Else
    strComputer=objArgs.Item(0)

End If

If objArgs.Item(1)="" Then
    strAdmin=""
Else
    strAdmin=objArgs.Item(1)
        If objArgs.Item(2)="" Then
            WScript.Echo "You forgot to specify a password for " &_
             strAdmin
            WScript.Quit
        Else
            strPassword=objArgs.Item(2)
        End If
End If

If (strComputer="." Or UCase(strComputer)= _
UCase(objNetwork.ComputerName) Or _
UCase(strComputer)="LOCALHOST") And strAdmin<>"" Then
    WScript.Echo "You can't use alternate credentials " &_
    "for local connections.  Connecting with existing " &_
    "credentials."
    strAdmin=""
    strPassword=""
End If

WScript.Echo "Connecting to " & strComputer

Set objLocator = CreateObject("WbemScripting.SWbemLocator")
Set objWMI = objLocator.ConnectServer( _
 strComputer, "root\cimv2", strAdmin, strPassword)

strWMIQuery = "SELECT * FROM Win32_OperatingSystem"
Set colResults = objWMI.ExecQuery(strWMIQuery)
For Each objResult In colResults
     WScript.echo "OS = " & objResult.Caption
Next